Xorscr

        LD A,(#5B5C)
        XOR %00001010
        LD (#5B5C),A
        LD BC,#7FFD
        OUT (C),A
        RET 
;- ----------------------------------------------------------- -
Pages

        AND %00001111 ; A - Номер страницы
        OR %00010000  ;BC - Используется в своих целях
        LD BC,#7FFD
        OUT (C),A     ;Страница перекючилась
        LD (#5B5C),A
        RET 
;- ----------------------------------------------------------- -
HL_Scr

        LD A,L        ;HL - Координата X-H  Y-L
        AND 7         ; A - Используется в своих целях
        RRCA 
        RRCA          ;HL - Адрес экрана
        RRCA 
        ADD A,H
        LD H,L
        LD L,A
        LD A,H
        AND #18
        OR #40
        LD H,A
        RET 
;- ----------------------------------------------------------- -
DE_Scr

        LD A,E        ;DE - Координата X-D  Y-E
        AND 7         ; A - Используется в своих целях
        RRCA 
        RRCA          ;DE - Адрес экрана
        RRCA 
        ADD A,D
        LD D,E
        LD E,A
        LD A,D
        AND #18
        OR #40
        LD D,A
        RET 
;- ----------------------------------------------------------- -
HL_Atr

        LD A,H        ;HL - Координата X-H  Y-L
        ADD HL,HL     ; A - используется в своих целях
        ADD HL,HL
        ADD HL,HL     ;HL - Адрес атрибутов
        LD H,#16
        ADD HL,HL
        ADD HL,HL
        ADD A,L
        LD L,A
        LD A,H
        OR #40
        LD H,A
        RET 
;- ----------------------------------------------------------- -
HL_Up8

        LD A,L
        SUB 32
        LD L,A
        RET NC
        LD A,H
        SUB 8
        LD H,A
        RET 
;- ----------------------------------------------------------- -
DE_Up8

        LD A,E
        SUB 32
        LD E,A
        RET NC
        LD A,D
        SUB 8
        LD D,A
        RET 
;- ----------------------------------------------------------- -
HL_Down8

        LD A,L
        ADD A,32
        LD L,A
        RET NC
        LD A,H
        ADD A,8
        LD H,A
        RET 
;- ----------------------------------------------------------- -
DE_Down8

        LD A,E
        ADD A,32
        LD E,A
        RET NC
        LD A,D
        ADD A,8
        LD D,A
        RET 
;- ----------------------------------------------------------- -
HL_Down

        INC H         ; А - Используется в своих целях
        LD A,H
        AND 7         ;HL - На один пиксель ниже в экран. обл.
        RET NZ
        LD A,L
        ADD A,32
        LD L,A
        RET C
        LD A,H
        SUB 8
        LD H,A
        RET 
;- ----------------------------------------------------------- -
DE_Down

        INC D         ; A - Ипользуется в своих целях
        LD A,D
        AND 7         ;DE - На один пиксель ниже в экран. обл.
        RET NZ
        LD A,E
        ADD A,32
        LD E,A
        RET C
        LD A,D
        SUB 8
        LD D,A
        RET 
;- ----------------------------------------------------------- -
HL_Up

        DEC H         ; А - Используется в своих целях
        LD A,H
        AND 7         ;HL - На один пиксель выше в экран. обл.
        CP 7
        RET NZ
        LD A,L
        SUB 32
        LD L,A
        RET C
        LD A,H
        ADD A,8
        LD H,A
        RET 
;- ----------------------------------------------------------- -
Atr_Scr

        LD A,H		;HL - Преобразует из атрибут в экарнную
        SLA H
        SLA H
        SLA H
        AND %10000000
        XOR H
        XOR %10000000
        AND %10011000   ;Последние три бита это линия
        OR %01000000   ;Тоже самое
        LD H,A
        RET 
;- ----------------------------------------------------------- -
Scr_Atr

        LD A,H
        SRL H
        SRL H
        SRL H
        AND %10000000
        OR H
        AND %10000011
        OR %01011000
        LD H,A
        RET 
;- ----------------------------------------------------------- -
Rnd

        LD HL,(SEED)
        CALL RND
RND     LD A,H
        ADD HL,HL
        XOR H
        ADD HL,HL
        ADD HL,HL
        ADD HL,HL
        XOR H
        ADD HL,HL
        ADD HL,HL
        XOR H
        ADD HL,HL
        ADD HL,HL
        LD L,A
        LD (SEED),HL
        RET 
SEED    DW  #FFFF ; НЕ НОЛЬ!
;- ----------------------------------------------------------- -
BreakIm1

        DI 
        LD A,#3F
        LD I,A
        IM 1
        EI 
        RET 
;- ----------------------------------------------------------- -
BreakIm2
        DI 
        LD HL,#BE00
        LD A,H
        LD I,A
        INC A
_IM2    LD (HL),A
        INC L
        JP NZ,_IM2
        INC H
        LD (HL),A
        LD HL,Breaking_2 ; где будет сама обработка
        LD (#BFBF+1),HL
        LD HL,#BFBF
        LD (HL),#C3
        IM 2
        EI 
        RET